Распаковка Still Wakes the Deep (UE 5.3.2)

[PROFFESIONAL 1]

Доброго времени суток! Хотим локализировать новинку “Still Wakes the Deep”, но познаний в распаковке, в экспорте звуков и их импорте обратно в игровые архивы — нет. Игровые архивы удалось распаковать с помощью программы “FModel”, файлы идут в формате .uasset и .ubulk, но вот что делать дальше — не понимаю, версия движка игры UE 5.3.2. Поможет кто-то из знающих? Заранее спасибо!

Изменено Четверг в 11:12 пользователем PROFFESIONAL

[xoixa 50]

Извлечение и конвертации звука из игры Still Wakes the Deep

0. Извлечь .uasset и .ubulk файлы(Habitat/Content/Habitat/Audio/WwiseAudio/) из Habitat-Windows.ucas в папки Media и ExternalSources
0. Установить audiokinetic wwise 2021.1.* (скачать автономный установщик можно, например здесь (нужна регистрация))
0. Распаковать все файлы из архива рядом с папками Media и ExternalSources
1. Запустить ubulk2wav.bat для переименования и разжатия звука согласно файла names.txt (в папку wav)
2. Переозвучить файлы из папки wav (озвученные файлы должны быть с теми же характеристиками что и оригиналы (имя, длительность, дискретизация, количество дорожек) в формате wav PCM s16). Лишние wav файлы без озвучки лучше удалить
3. Запустить wav2ubulk.bat. В папке pack_me появятся файлы, готовые для запаковки в utoc+ucas

 

Скрытый текст

@echo off
set packpath=pack_me\Habitat\Content\Habitat\Audio\WwiseAudio

:convert
echo convert wavs to adpcm wems
REM Create ExternalSourcesList list.txt for WwiseCLI tool
echo ^<^?xml version=^"1.0^" encoding=^"UTF-8^"^?^> > list.txt
echo ^<ExternalSourcesList SchemaVersion=^"1^" Root=^"^"^> >> list.txt
for %%s in (wav\*.wav) do echo 	^<Source Path=^"%%~fs^" Conversion=^"ADPCM As Input^" /^> >> list.txt
echo ^</ExternalSourcesList^> >> list.txt

REM Convert wavs to wem
"%WWISEROOT%\Authoring\x64\Release\bin\WwiseCLI.exe" dummy.wproj -ConvertExternalSources list.txt -ExternalSourcesOutput wem
RMDIR /S /Q .cache, Originals
del /A:h wem\Wwise.dat
del list.txt

:rename
echo rename Name.ID.wem to ID.ubulk and move to pack_me folder with corresponding uasset
if not exist "%packpath%\ExternalSources\" md "%packpath%\ExternalSources\"
if not exist "%packpath%\Media\" md "%packpath%\Media\"

::%%1 size	%%2 mediaID	%%3 name
for /f "tokens=1,2,3 delims=," %%1 in (names.txt) do IF exist "wem/%%3.%%2.wem" move /Y "wem\%%3.%%2.wem" "%packpath%\Media\%%2.ubulk" & copy /Y "Media\%%2.uasset" "%packpath%\Media\%%2.uasset"
for %%1 in (wem\*.wem) do move "wem\%%~n1.wem" "%packpath%\ExternalSources\%%~n1.ubulk" & copy "ExternalSources\%%~n1.uasset" "%packpath%\ExternalSources\%%~n1.uasset"

:size
echo put new size in uassets
for %%1 in (%packpath%\Media\*.ubulk) do quickbms -o size.bms "%%1" "%packpath%\Media"
for %%1 in (%packpath%\ExternalSources\*.ubulk) do quickbms -o size.bms "%%1" "%packpath%\ExternalSources"
:end
@pause

 

Скрытый текст

get NewSize asize #new ubulk size
open FDDE "uasset" #open uasset file
get UassetSize asize
get UassetName filename

#parse uasset file
get Null long
get Offset long
math Offset + 6
goto Offset
get NameSize long
getDString Name NameSize #ubulk name
math Offset - 0x12E
goto Offset
get Dummy longlong
savepos SizeOffset
get OldSize long #ubulk size

#write new size to uasset
log MEMORY_FILE 0 UassetSize
putvarchr MEMORY_FILE SizeOffset NewSize long 
log UassetName 0 UassetSize MEMORY_FILE  */

 

ps. Все файлы с голосом пожаты ADPCM, насколько я понял. Если понадобиться пожать звук в Vorbis, в файле wav2ubaulk.bat заменить

Conversion=^"ADPCM As Input^"

на

Conversion=^"Vorbis Quality High^"